//設定---------------------------------------------
//-----------------以下すべて、1:オン 0:オフ-------

	color_scheme = 1;	//配色 (1:白/2:黒)
	autoplay = 0;		//オートプレイ (1:する/0:しない)
	q_button = 1;		//画質ボタン (1:表示/0:非表示)
	percentage = 1;		//パーセント数値 (1:表示/0:非表示)
	stat_view = 1;		//ロードステータス (1:表示/0:非表示)
	parts_stretch = 0;	//パーツの引き伸ばし (1:する/0:しない)
	test_preview = 0;	//テストプレビュー (1〜:ON/0:OFF)

//以下はいじらない==============================================
	if(test_preview != 0){pb.removeMovieClip();}
	x = Stage.width/100;	y = Stage.height/100;
	if(parts_stretch == 1){_global.sc = Stage.height/240;}else{_global.sc = 1;}
	loaded = 0;	t_border = 0;

if(color_scheme == 1){
	c_pb1 = 0x888888;	c_qb1 = 0xaaaaaa;	c_per = 0x444444;
	c_pb2 = 0x222222;	c_qb2 = 0x222222;	c_stat = 0x777777;
	c_bg = 0xffffff;	c_mt = 0x444444;
}else if(color_scheme == 2){
	c_pb1 = 0xbbbbbb;	c_qb1 = 0x999999;	c_per = 0xbbbbbb;
	c_pb2 = 0xffffff;	c_qb2 = 0xdddddd;	c_stat = 0xcccccc;
	c_bg = 0x000000;	c_mt = 0xcccccc;
}

//ムービークリップ生成
function cMC(name,depth,x,y,target){
	if(target){eval(target).createEmptyMovieClip(name,depth);name=target+"."+name;}
	else{createEmptyMovieClip(name,depth);}
	with(eval(name)){	_x = x;	_y = y;
		_xscale = _yscale = sc*100;}
};

//テキスト生成
function cTX(name,depth,value,x,y,w,h,align,tf){
	if(align.indexOf("l")!=-1){tx = 0;}else if(align.indexOf("r")!=-1){tx = -w;}else{tx=-w/2;}
	if(align.indexOf("t")!=-1){ty = 0;}else if(align.indexOf("b")!=-1){ty = -h;}else{ty=-h/2;}
	cMC(name,depth,x,y);
	eval(name).createTextField(name,1,tx,ty,w,h);
	with(eval(name+"."+name)){
		text = value;
		selectable = false;
		setTextFormat(tf);
		if(_parent._parent.t_border == 1){border = true;}
	}
};

//テキストフォーマット設定
function cTF(name,sz,cl,fn,ag,st){
	with(eval(name)){
		size = sz;	color = cl;
		font = fn;	align = ag;
		if(st.indexOf("b") == -1){bold = false;}else{bold = true;}
		if(st.indexOf("i") == -1){italic = false;}else{italic = true;}
		if(st.indexOf("u") == -1){underline = false;}else{underline = true;}
}};

//画質設定
function setQuality(q){
	_quality = q;
	qh.qh.setTextFormat(TFqb1);	qm.qm.setTextFormat(TFqb1);	ql.ql.setTextFormat(TFqb1);
	if(_quality == "HIGH"){qh.qh.setTextFormat(TFqb2);}
	else if(_quality == "MEDIUM"){qm.qm.setTextFormat(TFqb2);}
	else if(_quality == "LOW"){ql.ql.setTextFormat(TFqb2);}
};

//ステータス制御-----------------------------------------------------
function onEnterFrame(){
	if(loaded < 100){
		if(_root._currentframe > 1){_root.gotoAndStop(1);}
		if(test_preview == 0){loaded = Math.floor(_root.getBytesLoaded()/_root.getBytesTotal()*100);}
		else if(test_preview != 0){loaded += test_preview;}
		per.per.text = loaded + "%";
		per.per.setTextFormat(TFper);
		with(mtMC){
			clear();	lineStyle(3,c_mt,100);
			moveTo (0,80*y);	lineTo (loaded*x,80*y);}
	}else if(loaded == 100){
		if(autoplay == 1){_root.Play();}else{
			cTX("pb",300,">Play",x*50,y*45,56,28,"cm",TFpb1);
			pb.onPress = function(){_root.Play();};
			pb.onRollOver = function(){pb.pb.setTextFormat(TFpb2);};
			pb.onRollOut = function(){pb.pb.setTextFormat(TFpb1);};
			stat_txt.stat_txt.text = "completed.";
			stat_txt.stat_txt.setTextFormat(TFstat);
		}
		loaded = 200;
	}
};

//テキストフォーマット

	TFpb1 = new TextFormat();	//PlayButton1
	TFpb2 = new TextFormat();	//PlayButton2
	TFqb1 = new TextFormat();	//QualityButton1
	TFqb2 = new TextFormat();	//QualityButton2
	TFper = new TextFormat();	//PercentageText
	TFstat = new TextFormat();	//StatusText

	cTF("TFpb1",20,c_pb1,"_serif","center","b");
	cTF("TFpb2",20,c_pb2,"_serif","center","b");
	cTF("TFqb1",14,c_qb1,"_serif","center","b");
	cTF("TFqb2",14,c_qb2,"_serif","center","b");
	cTF("TFper",22,c_per,"_serif","right","bi");
	cTF("TFstat",12,c_stat,"_serif","left","i");

//-------------------------------------画質ボタン
if(q_button == 1){
	cTX("qh",201,"High",5*sc,5*y,42,22,"lm",TFqb1);
	cTX("qm",202,"Medium",47*sc,5*y,58,22,"lm",TFqb1);
	cTX("ql",203,"Low",105*sc,5*y,36,22,"lm",TFqb1);

	if(_quality == "HIGH"){setQuality("HIGH");}
	else if(_quality == "MEDIUM"){setQuality("MEDIUM");}
	else if(_quality == "LOW"){setQuality("LOW");}

        qh.onPress = function(){setQuality("HIGH");};
        qm.onPress = function(){setQuality("MEDIUM");};
        ql.onPress = function(){setQuality("LOW");};
}

//-------------------------------------％表示
if(percentage == 1){cTX("per",200,0,50*x,90*y,60,40,"cm",TFper);}

//-------------------------------------ステータス
if(stat_view == 1){cTX("stat_txt",100,"Now loading...",2*x,98*y,150,19,"lb",TFstat);}

//-------------------------------------背景
createEmptyMovieClip("bgMC",1);
with(bgMC){
	lineStyle();
	beginFill(c_bg,100);
	lineTo(x*100,0);
	lineTo(x*100,y*100);
	lineTo(0,y*100);
	lineTo(0,0);
	endFill();
}
createEmptyMovieClip("mtMC",2);